Készítse el az alábbi két űrlapot!
A Form1űrlapon megjelenített vezérlők a következők:
A Form2űrlapon megjelenített vezérlők a következők:
A Form1 teljes programkódja:
Dim Adatok() As Integer
Dim mennyiseg As Integer
Sub Beolvasas()
Dim Adat As String
mennyiseg = 0
Do
Adat = InputBox("Kérem a(z) " & mennyiseg + 1 & ". adatot!")
If Adat <> "" Then
mennyiseg = mennyiseg + 1
ReDim Preserve Adatok(1 To mennyiseg)
Adatok(mennyiseg) = Val(Adat)
End If
Loop Until Adat = ""
MsgBox (mennyiseg & " db adat beolvasása megtörtént.")
End Sub
Sub Osszegzes()
MsgBox ("A tömb elemeinek összege: " & Osszeg())
End Sub
Function Osszeg()
Dim i As Integer
Dim Sum As Long
Sum = 0
For i = 1 To mennyiseg
Sum = Sum + Adatok(i)
Next
Osszeg = Sum
End Function
Sub Atlagolas()
Dim Atlag As Double
Atlag = Osszeg() / mennyiseg
MsgBox ("A tömb elemeinek átlaga: " & Round(Atlag, 2))
End Sub
Sub Minimum()
Dim Min As Integer
Dim i As Integer
Min = Adatok(1)
For i = 2 To mennyiseg
If Min > Adatok(i) Then
Min = Adatok(i)
End If
Next
MsgBox ("A tömb legkisebb eleme a(z) " & Min & ".")
End Sub
Sub Maximum()
Dim Max As Integer
Dim i As Integer
Max = Adatok(1)
For i = 2 To mennyiseg
If Max < Adatok(i) Then
Max = Adatok(i)
End If
Next
MsgBox ("A tömb legnagyobb eleme a(z) " & Max & ".")
End Sub
Sub Sorbarendezes()
Dim Min As Integer
Dim index As Integer
Dim VoltCsere As Boolean
Dim i As Integer, j As Integer
For i = 1 To mennyiseg - 1
Min = Adatok(i)
index = i
VoltCsere = False
For j = i + 1 To mennyiseg
If Adatok(j) < Min Then
Min = Adatok(j)
index = j
VoltCsere = True
End If
Next
If VoltCsere Then
Adatok(index) = Adatok(i)
Adatok(i) = Min
End If
Next
End Sub
Private Sub Command1_Click()
Dim VanElem As Boolean
Beolvasas
VanElem = mennyiseg > 0
Command2.Enabled = VanElem
Command3.Enabled = VanElem
Command4.Enabled = VanElem
Command5.Enabled = VanElem
Command6.Enabled = VanElem
End Sub
Private Sub Command2_Click()
Osszegzes
End Sub
Private Sub Command3_Click()
Atlagolas
End Sub
Private Sub Command4_Click()
Minimum
End Sub
Private Sub Command5_Click()
Maximum
End Sub
Private Sub Command6_Click()
Dim i As Integer
Form2.List1.Clear
Form2.List2.Clear
For i = 1 To mennyiseg
Form2.List1.AddItem (Adatok(i))
Next
Sorbarendezes
For i = 1 To mennyiseg
Form2.List2.AddItem (Adatok(i))
Next
Form2.Show vbModal, Me
End Sub
A Form2 teljes programkódja
Private Sub Command1_Click()
Me.Hide
End Sub